home *** CD-ROM | disk | FTP | other *** search
/ 8bitfiles.net/archives / archives.tar / archives / c64-preservation-project / educational / intro_to_basic_part_1[cbm_1983].nbz / sentences (.txt) < prev    next >
Encoding:
Commodore BASIC  |  2019-04-13  |  2.6 KB  |  101 lines
  1. 3 REM SENTENCES(UNIT 6)
  2. 5 REM COPYRIGHT (C) ANDREW COLIN 1981
  3. 10 N=13
  4. 20 DIMP(13,2)
  5. 30 GOSUB2000
  6. 40 GOSUB100
  7. 45 PRINT"[147]"
  8. 46 X$=MID$(X$,2,LEN(X$)-1)+"."
  9. 50 GOSUB5000
  10. 60 PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT"FOR THE NEXT SENTENCE"
  11. 70 PRINT"HIT ANY KEY"
  12. 80 X=RND(1)
  13. 90 GETA$:IFA$=""THEN80  LIST0-100
  14. 95 GOTO40
  15. 100 REM MAIN SENTENCE GENERATOR
  16. 105 X$=""
  17. 110 IF RND(1)<0.5THEN300
  18. 120 GOSUB1100
  19. 130 IFRND(1)<0.3THEN700
  20. 140 IFRND(1)<0.5THEN170
  21. 150 A=2:GOSUB1000
  22. 160 GOSUB1200:GOTO800
  23. 170 A=3:GOSUB1000
  24. 180 A=4:GOSUB1000
  25. 190 GOTO800
  26. 300 GOSUB1200
  27. 310 IFRND(1)<0.3THEN700
  28. 320 IFRND(1)>0.5THEN370
  29. 330 A=2:GOSUB1000
  30. 340 GOSUB1100
  31. 350 GOTO800
  32. 370 A=3:GOSUB1000
  33. 380 A=5:GOSUB1000
  34. 390 GOTO800
  35. 700 A=1:GOSUB1000:GOTO900
  36. 800 IFRND(1)<0.6THEN RETURN
  37. 810 A=6:GOSUB1000:RETURN
  38. 900 IFRND(1)>0.5THEN RETURN
  39. 910 A=7:GOSUB1000:RETURN
  40. 1000 REM SUBROUTINE TO SELECT A RANDOM WORD FROM CATEGORY A.
  41. 1005 Y=P(A,1)+INT((P(A,2)-P(A,1)+1)*RND(1))
  42. 1010 RESTORE:FORZ=1TOY:READY$:NEXT
  43. 1020 X$=X$+" "+Y$
  44. 1030 RETURN
  45. 1100 REM SELECT MALE SUBJECT.
  46. 1105 IFRND(1)>0.5THEN1120
  47. 1110 A=8:GOSUB1000:RETURN
  48. 1120 X$=X$+" THE"
  49. 1130 IF RND(1)<0.4THENA=9:GOSUB1000
  50. 1140 A=10:GOSUB1000
  51. 1150 RETURN
  52. 1200 REM SELECT FEMALE SUBJECT.
  53. 1205 IFRND(1)>0.5THEN1220
  54. 1210 A=11:GOSUB1000:RETURN
  55. 1220 X$=X$+" THE"
  56. 1230 IFRND(1)<0.4THENA=12:GOSUB1000
  57. 1240 A=13:GOSUB1000:RETURN
  58. 2000 REM SET UP POINTER TABLE
  59. 2010 X=1
  60. 2020 FORJ=1TON
  61. 2030 P(J,1)=X
  62. 2040 READX$
  63. 2050 IFX$<>"Z"THENX=X+1:GOTO2040
  64. 2060 P(J,2)=X-1:X=X+1
  65. 2070 NEXTJ
  66. 2090 RETURN
  67. 5000 REM DISPLAY SENTENCE X$ WITHOUT BREAKING UP WORDS ACROSS LINES
  68. 5005 IFLEN(X$)>40THEN5020
  69. 5010 PRINTX$:RETURN
  70. 5020 IF MID$(X$,41,1)<>"[160]"THEN 5050
  71. 5030 PRINTMID$(X$,1,40)
  72. 5040 X$=RIGHT$(X$,LEN(X$)-41):PRINT
  73. 5045 GOTO5000
  74. 5050 IFMID$(X$,41,1)<>" "THEN5080
  75. 5060 PRINTMID$(X$,1,40)
  76. 5065 X$=MID$(X$,41,LEN(X$)-40):PRINT
  77. 5070 GOTO5000
  78. 5080 P=39
  79. 5090 IFMID$(X$,P,1)<>" "THENP=P-1:GOTO5090
  80. 5100 PRINTMID$(X$,1,P-1) :PRINT
  81. 5110 X$=MID$(X$,P+1,LEN(X$)-P)
  82. 5120 GOTO5000
  83. 9000 DATAGRUNTS,SINGS,HUMS,PLAYS THE BANJO,KEEPS THE RADIO ON,Z
  84. 9010 DATAMET,SHOOK HANDS WITH,HAD A DRINK WITH,GREETED,KISSED,ATTACKED
  85. 9011 DATAGLOATED OVER,DISDAINED,DID NOT RECOGNISE,WALKED RIGHT PAST,Z
  86. 9020 DATATOOK  OFF, REMOVED,DISCARDED,SOLD,WASHED,WAGERED,Z
  87. 9030 DATAHIS SHIRT,HIS SHOES,HIS COAT,HIS SOCKS,HIS TOUPEE,HIS WATCH,Z
  88. 9040 DATAHER WIG,HER SHOES,HER HAT,HER SPECTACLES,HER STOCKINGS,HER WELLIES,Z
  89. 9050 DATAWITH DELIGHT,IN THE PARK,EVERY DAY,YESTERDAY,LAST WEEK,THIS MORNING
  90. 9051 DATAIN THE PUBLIC LIBRARY,IN THE SWIMMING POOL,IN THE HOME COMPUTER SHOP,Z
  91. 9060 DATAALL THE TIME,OFTEN,IN THE BATH,QUIETLY,LOUDLY,Z
  92. 9070 DATA PRESIDENT REAGAN,MR.ANDROPOV,THE AYATOLLAH KHOMEINI,MR.FOOT
  93. 9071 DATA FLIGHT LIEUTENANT JERRY RAWLINGS,COL. GHADAFI,PRINCE CHARLES,Z
  94. 9080 DATA CLEVER,HUSKY,BURLY,FAT,STUPID,HALFWITTED,AIMIABLE,GRUBBY,ELEGANT,Z
  95. 9090 DATAENGINE DRIVER,PILOT,PROFESSOR,LAVATORY ATTENDANT,FOOTBALLER,LIBRARIAN
  96. 9091 DATACHIEF DESIGNER OF THE COMMODORE 64,CBM SALESMAN,Z
  97. 9100 DATAMRS.THATCHER,JANE FONDA,KATE BUSH,VANESSA REDGRAVE,PRINCESS ANNE
  98. 9101 DATAMRS. EDNA EVERAGE,PRINCESS DIANA,GLENDA JACKSON,KIRI TE KANAWA,Z
  99. 9110 DATABEAUTIFUL,PRETTY,UGLY,PLAIN,CURVACEOUS,FASCINATING,BRAINY,DEMENTED,Z
  100. 9120 DATAGIRL,POLICEWOMAN,BARMAID,CONDUCTRESS,SECRETARY,YOUNG LADY,DOWAGER,Z
  101.